ਸਾਰ

Related Calculations

${\displaystyle {\hat {f}}(\xi )=\int _{-{1 \over 2}}^{1 \over 2}e^{-2\pi ix\xi }dx={\frac {i}{2\pi \xi }}(e^{-\pi i\xi }-e^{\pi i\xi })={\frac {\sin \pi \xi }{\pi \xi }}.}$

${\displaystyle {\hat {g}}(\xi )=\int _{0}^{1}e^{-2\pi ix\xi }dx={\frac {i}{2\pi \xi }}(e^{-2\pi i\xi }-1)={\frac {1}{2\pi \xi }}\sin 2\pi \xi +i{\frac {1}{2\pi \xi }}(\cos 2\pi \xi -1).}$

Gnuplot Source Code

# Author: Slawekb, Ika, 2015-08-15
# Slawekb gave the analogous plot using Mathematica: https://en.wikipedia.org/wiki/File:Fourier_transform_of_rect_and_a_translation.png
# Anyone can copy and revise this code without any copyright concern.

set term svg size 800,600 enhanced font 'Times, 16'
set output 'fourier_unit_pulse.svg'

unset tics
unset border
unset colorbox
set sample 1000
set multiplot

set arrow from -3,0 to 3,0 nohead lw 2
set arrow from 0,-0.3 to 0,1.05 nohead lw 2

# Figure (a)
set size 0.5, 0.5
set origin 0.0, 0.5

unset key 
set yrange [-0.5:1.5]
plot [-3:3] -0.5 <= x && x <= 0.5 ? 1 : 0 w lines lw 2 lc rgb 'blue' t 'f'
unset yrange

# Figure (b)
set size 0.5, 0.5
set origin 0.5, 0.5

set key font "Times, 22"

plot [-3:3] (sin(pi*x))/(x*pi) w lines lw 2 t 'Re', 0 w lines t 'Im' lw 2
			

# Figure (c)
set size 0.5, 0.5
set origin 0.0, 0.0

unset key 
set yrange [-0.5:1.5]

plot [-3:3] 0.0 <= x && x <= 1.0 ? 1 : 0 w lines lw 2 lc rgb 'blue' t 'g'
unset yrange

# Figure (d)
set arrow from 0,-0.8 to 0,-0.2 nohead lw 2
set size 0.5, 0.5
set origin 0.5, 0.0

set key font "Times, 22"

plot [-3:3] (sin(2*pi*x))/(x*2*pi) w lines lw 2 t 'Re', (cos(2*pi*x)-1)/(2*pi*x) w lines t 'Im' lw 2

unset multiplot
set term windows
set output

ਲਸੰਸ

I, the copyright holder of this work, hereby publish it under the following license:

This file is licensed under the Creative Commons Attribution-Share Alike 4.0 International license.

ਤੁਹਾਨੂੰ ਖੁੱਲ੍ਹ ਹੈ:

• ਸਾਂਝਾ ਕਰਨ ਦੀ – ਰਚਨਾ ਨੂੰ ਕਾਪੀ, ਵੰਡਣਾ ਅਤੇ ਭੇਜਣਾ
• ਮੁੜ-ਰਲ਼ਾਉਣ ਦੀ – ਰਚਨਾ ਨੂੰ ਢਾਲਣਾ

ਥੱਲੇ ਲਿਖੀਆਂ ਸ਼ਰਤਾਂ ਹੇਠ:

• ਗੁਣਾਂ ਦੀ ਦੱਸ – ਉਚਿਤ ਕ੍ਰੈਡਿਟ ਦੇਵੋ, ਲਾਇਸੰਸ ਦਾ ਇੱਕ ਲਿੰਕ ਪ੍ਰਦਾਨ ਕਰੋ ਅਤੇ ਇਹ ਦਰਸਾਓ ਕਿ ਕੀ ਤਬਦੀਲੀਆਂ ਕੀਤੀਆਂ ਗਈਆਂ ਸਨ। ਤੁਸੀਂ ਇਹ ਕਿਸੇ ਵੀ ਵਾਜਬ ਤਰੀਕੇ ਨਾਲ ਕਰ ਸਕਦੇ ਹੋ, ਪਰ ਇਹ ਤਰੀਕਾ ਅਜਿਹਾ ਨਹੀਂ ਹੋਣਾ ਚਾਹੀਦਾ ਜੋ ਇਹ ਦਰਸਾਵੇ ਕਿ ਲਾਇਸੰਸਕਰਤਾ ਤੁਹਾਨੂੰ ਜਾਂ ਤੁਹਾਡੀ ਵਰਤੋਂ ਦਾ ਸਮਰਥਨ ਕਰਦਾ ਹੈ।
• ਸ਼ੇਅਰ ਅਲਾਈਕ – ਜੇਕਰ ਤੁਸੀਂ ਸਮੱਗਰੀ ਨੂੰ ਰੀਮਿਕਸ ਕਰਦੇ ਹੋ, ਬਦਲਦੇ ਹੋ ਜਾਂ ਬਣਾਉਂਦੇ ਹੋ, ਤਾਂ ਆਪਣੇ ਯੋਗਦਾਨ ਇੱਕੋ ਜਿਹੇ ਜਾਂ ਅਨੁਕੂਲ ਲਾਇਸੰਸ ਦੇ ਅਧੀਨ ਕਰੋ।

https://creativecommons.org/licenses/by-sa/4.0CC BY-SA 4.0 Creative Commons Attribution-Share Alike 4.0 truetrue